Memory leak when Puppy is used inside a thread #123

import std / strutils
import std / os
import puppy

type ThreadParams = object
  url: string
  responseBody: string
  success: bool
  errorMsg: string

proc requestThreadFunc(params: ptr ThreadParams) {.thread.} =
  try:
    params.responseBody = puppy.fetch(params.url)
    params.success = true
  except:
    params.errorMsg = getCurrentExceptionMsg()
    params.success = false

proc requestBody*(url: string): string =
  template cleanup() =
    `=destroy`(params[])
    deallocShared(params)

  var params = createShared(ThreadParams)
  params.url = url
  var thread: Thread[ptr ThreadParams]
  createThread(thread, requestThreadFunc, params)
  # while thread.running():
    # process UI events
  joinThreads(thread)
  if not params.success:
    let errorMsg = params.errorMsg
    cleanup()
    raise newException(CatchableError, errorMsg)
  result = move(params.responseBody)
  cleanup()

proc showMemoryUsage() =
  var rss: string
  for line in lines("/proc/self/status"):
    if line.startsWith("VmRSS:"):
      rss = line.splitWhitespace()[1]
      break
  echo "RSS: ", rss, " kB, getOccupiedMem: ", getOccupiedMem() div 1000, " kB"

proc main() =
  while true:
    discard requestBody("https://google.com")
    showMemoryUsage()
    os.sleep(200)

main()