Array Binding Does Not Work #525

#!/usr/bin/perl -w

use v5.28;
use strict;
use warnings;
use utf8;
use DBI;
use Test::More;

my $dbh = DBI->connect('dbi:ODBC:Server=clickhouse;Database=default;Driver=ClickHouse', '', '', {
    PrintError  => 0,
    RaiseError  => 1,
    AutoCommit  => 1,
});

END { $dbh->disconnect if $dbh }

$dbh->do(q{
    CREATE TABLE IF NOT EXISTS posts (
        id   INT         PRIMARY KEY,
        tags Array(TEXT) NOT NULL DEFAULT '[]'
    ) ENGINE=MergeTree
});

# Try just inserting an array.
eval {
    $dbh->do(
        'INSERT INTO posts VALUES (?, ?)',
        undef, 1, [qw(clickhouse perl)],
    );
};
is $@, undef, 'Should have inserted an array';

# Try using an explicit bind param.
my $sth = $dbh->prepare('INSERT INTO posts VALUES (?, ?)');
$sth->bind_param(1, 1);
local $@ = undef;
eval { $sth-> bind_param(2, [qw(clickhouse perl)], { TYPE => DBI::SQL_ARRAY}) };
is $@, undef, 'Should bound an array column';
# local $@ = undef;
# $sth->execute;
# is $@, undef, 'Should have inserted a bound array';

# Insert some tags to select.
$dbh->do(
    q{INSERT INTO posts VALUES (?, array('clickhouse', 'perl'))},
    undef, 1,
);

# Select the tags column.
my $tags = $dbh->selectcol_arrayref(
    'SELECT tags FROM posts WHERE id = ?',
    undef, 1,
)->[0];
# It is a string and not an array.
is_deeply $tags, [qw(clickhouse perl)], 'Should have selected an array';

# Try binding again.
$sth = $dbh->prepare('SELECT tags FROM posts WHERE id = ?');
local $@;
eval { $sth->bind_col(1, \$tags, { TYPE => DBI::SQL_ARRAY}) };
is $@, undef, 'Should have inserted an array';
# local $@ = undef;
# $sth->execute;
# is_deeply $tags, [qw(clickhouse perl)], 'Should have selected a bound array';

done_testing;