eka-ci/flake.nix at master · ekala-project/eka-ci · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
{
  description = "EkaCI flake";

  inputs = {
    utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    treefmt-nix.url = "github:numtide/treefmt-nix";
    fenix.url = "github:nix-community/fenix";
    fenix.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    {
      self,
      nixpkgs,
      utils,
      treefmt-nix,
      fenix,
    }:
    let
      localOverlay = import ./nix/overlay.nix fenix;
    in
    utils.lib.eachDefaultSystem (system: rec {
      legacyPackages = import nixpkgs {
        inherit system;
        overlays = [
          fenix.overlays.default
          localOverlay
          (final: prev: {
            dev-server = final.callPackage ./nix/dev-server.nix { };
            dev-shell = final.callPackage ./nix/dev-shell.nix { };
          })
        ];
      };

      packages.default = legacyPackages.eka-ci;
      packages.module-docs = legacyPackages.callPackage ./nix/option-docs.nix { flake = self; };
      devShells.default = legacyPackages.dev-shell;
      checks.module = import ./nix/module-test.nix self legacyPackages;
      formatter =
        let
          fmt = treefmt-nix.lib.evalModule legacyPackages {
            programs.rustfmt.enable = true;
            programs.elm-format.enable = true;
            programs.nixfmt.enable = true;
          };
        in
        fmt.config.build.wrapper;
    })
    // {
      overlays.default = localOverlay;
      nixosModules.daemon = import ./nix/module.nix self;
    };
}