build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    //https://developer.android.com/jetpack/androidx/releases/compose-kotlin
    ext.kotlin_version = '1.8.10'

    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}
plugins {
    id 'com.android.application' version '7.4.1' apply false
    id 'com.android.library' version '7.4.1' apply false
    id 'org.jetbrains.kotlin.android' version '1.7.10' apply false
}

task clean(type: Delete) {
    delete rootProject.buildDir
}
def getVersionCode = { ->
    try {
        def stdout = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'rev-list', '--first-parent', '--count', 'HEAD'
            standardOutput = stdout
        }
        return Integer.parseInt(stdout.toString().trim())
    } catch (ignored) {
        return -1;
    }
}

def getVersionName = { ->
    String versionName  = project.findProperty('versionName') ?: getVersionNameFromGit() ?: "VersionNameError"
    versionName = increaseVersionForPreRelease(versionName)
    return versionName.replaceFirst("^v", "")
}

private static String increaseVersionForPreRelease(String versionName) {
    if (isPreReleaseVersion(versionName)) {
        return versionName.replaceFirst("(\\d+\\.\\d+\\.)(\\d+)", {
            return it[1] + (it[2].toInteger() + 1)
        })
    }
    return versionName
}

private static boolean isPreReleaseVersion(String versionName) {
    versionName.contains('-')
}

private String getVersionNameFromGit() {
    try {
        def stdout = new ByteArrayOutputStream()
        exec {
            // v0.3.10-187-gef4be8c9-dirty
            commandLine 'git', 'describe', '--tags', '--dirty', '--exclude', 'v*-*'
            standardOutput = stdout
        }
        return stdout.toString().trim()
    } catch (ignored) {
        return null
    }
}

ext {
    gitVersionCode = getVersionCode()
    gitVersionName = getVersionName()
    APPLICATION_ID = "com.nihility.mipush"

    COMPILE_SDK = 34
    MIN_SDK = 26
    TARGET_SDK = 34
}