buildprof/justfile at main · LalitMaganti/buildprof · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
# Copyright 2026 The Buildprof Authors.
# SPDX-License-Identifier: Apache-2.0

set shell := ["bash", "-euo", "pipefail", "-c"]

# Show available development commands.
default:
    @just --list

# Build the Linux development image.
container-build:
    uv run dev/container build

# Start the persistent Linux development container.
container-start:
    uv run dev/container start

# Replace the persistent container with one using the current image.
container-recreate:
    uv run dev/container recreate

# Stop the development container.
container-stop:
    uv run dev/container stop

# Open an interactive shell in the development container.
container-shell:
    uv run dev/container shell

# Build the image and replace the development container.
bootstrap: container-build container-recreate

# Build Buildprof and run all conformance tests, or pass pytest arguments.
test *args:
    uv run dev/test {{args}}

# Confirm the build and test environment and collect the test suite.
check:
    uv run dev/test --collect-only

# Update the action default and docs example after changing Cargo.toml's version.
release-prepare:
    python3 infra/prepare-action-release

# Run the local checks required before packaging a release.
release-check:
    python3 infra/prepare-action-release --check
    cargo fmt --all -- --check
    cargo clippy --all-targets --locked -- -D warnings
    cargo test --all-targets --locked
    cargo package --allow-dirty --locked

# Checkout pinned Perfetto, apply patches, and link permanent overlays.
perfetto-setup:
    uv run tools/perfetto setup

# Capture committed Perfetto changes as the ordered patch series.
perfetto-capture:
    uv run tools/perfetto capture

# Move the Perfetto pin and reapply patches and overlays.
perfetto-uprev revision="latest":
    uv run tools/perfetto uprev {{revision}}

# Build the patched, self-hostable Perfetto UI.
perfetto-build-ui *args:
    uv run tools/perfetto build-ui {{args}}

# Serve the UI with live reload; open traces in it with `buildprof open --dev-server`.
perfetto-dev-server *args:
    uv run tools/perfetto dev-server {{args}}